Công thức chung
=INT(end-start)&" days "&TEXT(end-start,"h"" hrs ""m"" mins """)
Tóm lược
Để tính toán và hiển thị ngày, giờ và phút giữa hai ngày, bạn có thể sử dụng hàm TEXT với một chút trợ giúp từ hàm INT. Trong ví dụ được hiển thị, công thức trong D5 là:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins """)
Giải trình
Hầu hết công việc trong công thức này được thực hiện bởi hàm TEXT, hàm này áp dụng định dạng số tùy chỉnh cho giờ và phút cho một giá trị được tạo bằng cách trừ ngày bắt đầu cho ngày kết thúc.
TEXT(C5-B5,"h"" hrs ""m"" mins """)
Đây là ví dụ về nhúng văn bản vào định dạng số tùy chỉnh và văn bản này phải được bao quanh bởi một cặp dấu ngoặc kép bổ sung. Nếu không có thêm dấu ngoặc kép, định dạng văn bản tùy chỉnh sẽ giống như sau:
h "hrs" m "min"
Giá trị cho ngày được tính bằng hàm INT, hàm này chỉ trả về phần nguyên của ngày kết thúc trừ ngày bắt đầu:
INT(C5-B5) // get day value
Lưu ý: Mặc dù bạn có thể sử dụng "d" ở định dạng số tùy chỉnh cho ngày, giá trị sẽ đặt lại về 0 khi số ngày lớn hơn 31.
Bao gồm giây
Để bao gồm giây, bạn có thể mở rộng định dạng số tùy chỉnh như sau:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins ""s"" secs""")
Tổng số ngày, giờ và phút giữa các ngày
Để có được tổng số ngày, giờ và phút giữa một nhóm ngày bắt đầu và ngày kết thúc, bạn có thể điều chỉnh công thức bằng cách sử dụng SUMPRODUCT như sau:
=INT(SUMPRODUCT(ends-starts))&" days "&TEXT(SUMPRODUCT(ends-starts),"h"" hrs ""m"" mins """)
trong đó "kết thúc" đại diện cho phạm vi ngày kết thúc và "bắt đầu" đại diện cho phạm vi ngày bắt đầu. Trong ví dụ được hiển thị, D11 chứa công thức này:
=INT(SUMPRODUCT(C5:C9-B5:B9))&" days "&TEXT(SUMPRODUCT(C5:C9-B5:B9),"h"" hrs ""m"" mins """)
