Công thức chung
=NETWORKDAYS(start,end,holidays)*hours
Tóm lược
Để tính tổng số giờ làm việc giữa hai ngày, bạn có thể sử dụng công thức dựa trên hàm NETWORKDAYS, trong đó "start" là ngày bắt đầu, "end" là ngày kết thúc, "ngày lễ" là phạm vi bao gồm ngày, và "giờ" là số giờ làm việc trong một ngày làm việc. Trong ví dụ được hiển thị, công thức trong D7 là:
=NETWORKDAYS(B7,C7,holidays)*8
trong đó "ngày lễ" là phạm vi được đặt tên G6: G8.
Giải trình
Công thức này sử dụng hàm NETWORKDAYS tính tổng số ngày làm việc giữa hai ngày, có tính đến các ngày cuối tuần và (tùy chọn) ngày lễ. Ngày lễ, nếu được cung cấp, phải là một loạt các ngày Excel hợp lệ. Sau khi biết tổng số ngày làm việc, chúng chỉ đơn giản được nhân với một số giờ cố định mỗi ngày, 8 trong ví dụ minh họa.
Hàm NETWORKDAYS bao gồm cả ngày bắt đầu và ngày kết thúc trong phép tính và loại trừ cả Thứ Bảy và Chủ Nhật theo mặc định. Hàm cũng sẽ loại trừ các ngày lễ khi sau đó được cung cấp dưới dạng đối số "ngày lễ" dưới dạng một phạm vi ngày hợp lệ.
Trong ví dụ này được hiển thị, hai công thức đầu tiên sử dụng hàm NETWORKDAYS.
D6=NETWORKDAYS(B6,C6)*8 // no holidays D7=NETWORKDAYS(B7,C7,holidays)*8 // holidays provided
Nếu tuần làm việc của bạn bao gồm các ngày không phải từ Thứ Hai đến Thứ Sáu, bạn có thể chuyển sang hàm NETWORKDAYS.INTL, hàm này cung cấp đối số "cuối tuần" có thể được sử dụng để xác định ngày nào trong tuần là ngày làm việc và ngày cuối tuần. NETWORKDAYS.INTL có thể được định cấu hình giống như NETWORKDAYS, nhưng nó cung cấp một đối số bổ sung gọi là "cuối tuần" để kiểm soát những ngày nào trong tuần được coi là ngày làm việc.
4 công thức tiếp theo sử dụng hàm NETWORKDAYS.INTL:
D8=NETWORKDAYS.INTL(B8,C8)*8 // Mon-Fri, no holidays D9=NETWORKDAYS.INTL(B9,C9,11)*8 // Mon-Sat, no holidays D10=NETWORKDAYS.INTL(B10,C10)*8 // M-F, no holidays D11=NETWORKDAYS.INTL(B11,C11,1,holidays)*8 // M-F, w/ holidays
Nhấp vào tên chức năng ở trên để tìm hiểu thêm về các tùy chọn cấu hình.
Lịch làm việc tùy chỉnh
Công thức này giả định rằng tất cả các ngày làm việc đều có cùng số giờ làm việc. Nếu bạn cần tính giờ làm việc với lịch trình tùy chỉnh trong đó giờ làm việc thay đổi theo ngày trong tuần, bạn có thể thử công thức như sau:
=SUMPRODUCT(MID(schedule,WEEKDAY(ROW(INDIRECT(start&":"&end))),1)*ISNA(MATCH(ROW(INDIRECT(start&":"&end)),holidays,0)))
Bạn có thể tìm thấy lời giải thích ở đây.
