Công thức chung
(=MIN(IF(rng1=criteria1,IF(rng2=criteria2,values))))
Tóm lược
Để nhận được giá trị nhỏ nhất trong tập dữ liệu sử dụng nhiều tiêu chí (tức là để lấy IF MIN), bạn có thể sử dụng và công thức mảng dựa trên các hàm MIN và IF. Trong ví dụ được hiển thị, công thức trong I6 là:
(=MIN(IF(color=G6,IF(item=H6,price))))
Với màu "đỏ" và mục "mũ", kết quả là $ 8,00
Lưu ý: Đây là công thức mảng và phải được nhập bằng Ctrl + Shift + Enter
Giải trình
Ví dụ này sử dụng các phạm vi được đặt tên sau: "color" = B6: B14, "item" = C6: C14 và "price" = E6: E14. Trong ví dụ, chúng tôi có giá cho các mặt hàng ở các khu vực khác nhau. Mục đích là tìm giá tối thiểu cho một màu và mặt hàng nhất định.
Công thức này sử dụng hai hàm IF lồng nhau, được bao bọc bên trong MIN để trả về giá tối thiểu bằng hai tiêu chí. Bắt đầu với kiểm tra logic của câu lệnh IF đầu tiên, color = G6, các giá trị trong màu phạm vi được đặt tên (B6: B14) được kiểm tra so với giá trị trong ô G6, "red". Kết quả là một mảng như thế này:
(TRUE;TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE)
Trong kiểm tra logic cho câu lệnh IF thứ hai, mục = H6, các giá trị trong mục phạm vi được đặt tên (C6: C14) được kiểm tra so với giá trị trong ô H6, "hat". Kết quả là một mảng như thế này:
(TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE)
"Giá trị nếu đúng" cho câu lệnh IF thứ 2, phạm vi được đặt tên là "giá" (E6: E14), là một mảng như thế này:
(11;8;9;12;9;10;9;8;7)
Giá được trả lại cho mỗi mặt hàng trong phạm vi này chỉ khi kết quả của hai mảng đầu tiên ở trên là TRUE cho các mặt hàng ở vị trí tương ứng. Trong ví dụ cho thấy mảng cuối cùng bên trong MIN trông như thế này:
(11;8;9;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE)
Lưu ý những giá duy nhất "tồn tại" là những giá ở vị trí có màu "đỏ" và mặt hàng là "mũ".
Sau đó, hàm MIN trả về giá thấp nhất, tự động bỏ qua các giá trị FALSE.
Cú pháp thay thế sử dụng logic boolean
Bạn cũng có thể sử dụng công thức mảng sau, chỉ sử dụng một hàm IF cùng với logic boolean:
(=MIN(IF((color=G6)*(item=H6),price)))
Ưu điểm của cú pháp này là có thể dễ dàng thêm các tiêu chí bổ sung mà không cần thêm các hàm IF lồng nhau bổ sung.
Với hàm MINIFS
Hàm MINIFS, được giới thiệu trong Excel 2016 thông qua Office 365, được thiết kế để trả về giá trị tối thiểu dựa trên một hoặc nhiều tiêu chí mà không cần công thức mảng. Với MINIFS, công thức trong I6 trở thành:
=MINIFS(price,color,G6,item,H6)
Lưu ý: MINIFS sẽ tự động bỏ qua các ô trống đáp ứng tiêu chí. Nói cách khác, MINIFS sẽ không coi các ô trống đáp ứng tiêu chí là 0. Mặt khác, MINIFS sẽ trả về không (0) nếu không có ô nào phù hợp với tiêu chí.
