Công thức chung
=IF(logical_test,"P","")
Tóm lược
Để hiển thị dấu kiểm nếu giá trị được "cho phép" dựa trên danh sách hiện có các giá trị được phép, bạn có thể sử dụng công thức dựa trên hàm IF cùng với hàm COUNTIF. Trong ví dụ hiển thị, công thức trong C5 là:
=IF(COUNTIF(allowed,B5),"✓","")
trong phạm vi được phép là phạm vi được đặt tên E5: E9.
Giải trình
Công thức này là một ví dụ điển hình về lồng một hàm vào bên trong một hàm khác. Về cơ bản, công thức này sử dụng hàm IF được thiết lập để trả về dấu kiểm (✓) khi kiểm tra logic trả về TRUE:
=IF(logical_test,"✓","")
Nếu kiểm tra trả về FALSE, công thức trả về một chuỗi rỗng (""). Đối với bài kiểm tra logic, chúng tôi đang sử dụng hàm COUNTIF như sau:
COUNTIF(allowed,B5)
COUNTIF đếm số lần xuất hiện của giá trị trong B5 trong phạm vi được đặt tên được phép (E5: E9). Điều này có vẻ "ngược" đối với bạn, nhưng nếu bạn nghĩ lại thì nó cũng có lý. Nếu giá trị ở B5 được tìm thấy trong danh sách các giá trị được phép, COUNTIF sẽ trả về một số dương (trong trường hợp này là 1). Nếu không, COUNTIF sẽ trả về 0. Excel sẽ đánh giá bất kỳ số nào khác 0 là TRUE, vì vậy điều này hoạt động hoàn hảo như một bài kiểm tra logic cho IF.
IF sẽ chỉ trả về TRUE nếu giá trị được tìm thấy trong danh sách được phép, và nếu vậy, kết quả cuối cùng là một dấu kiểm (✓). Nếu giá trị không được tìm thấy trong danh sách được phép, COUNTIF trả về giá trị 0, được đánh giá là FALSE. Trong trường hợp đó, kết quả cuối cùng là một chuỗi rỗng (""), không hiển thị gì.
Với các giá trị cố định
Ví dụ trên hiển thị các giá trị được phép trong một phạm vi ô, nhưng các giá trị được phép cũng có thể được mã hóa cứng vào các công thức dưới dạng một hằng số mảng như sau:
=IF(COUNTIF(("red","blue","green"),B5),"✓","")
Ký tự dấu kiểm (✓)
Chèn một ký tự dấu kiểm trong Excel có thể là một thử thách đáng ngạc nhiên và bạn sẽ tìm thấy nhiều bài báo trên internet giải thích các cách tiếp cận khác nhau. Cách dễ nhất để đưa ký tự dấu kiểm (✓) được sử dụng trong công thức này vào Excel chỉ đơn giản là sao chép và dán nó. Nếu bạn đang sao chép từ trang web này, hãy dán vào thanh công thức để tránh kéo theo định dạng không mong muốn. Bạn cũng có thể sao chép và dán trực tiếp từ trang tính đính kèm.
Nếu bạn gặp sự cố với sao chép và dán, hãy thử biến thể này. Bản thân ký tự này là Unicode 2713 (U + 2713) và cũng có thể được nhập vào Excel bằng hàm UNICHAR như sau:
=UNICHAR(10003) // returns "✓"
Vì vậy, công thức ban đầu có thể được viết như thế này:
=IF(COUNTIF(allowed,B5),UNICHAR(10003),"")
Lưu ý: hàm UNICHAR đã được giới thiệu trong Excel 2013.
Mở rộng công thức
Ý tưởng cơ bản trong công thức này có thể được mở rộng theo nhiều cách thông minh. Ví dụ: ảnh chụp màn hình bên dưới hiển thị một công thức chỉ trả về một dấu kiểm khi tất cả các điểm kiểm tra ít nhất là 65:
Công thức trong G5 là:
=IF(NOT(COUNTIF(B5:F5,"<65")),"✓","")
Hàm NOT đảo ngược kết quả từ COUNTIF. Nếu bạn thấy điều này khó hiểu, bạn có thể thay phiên cấu trúc lại công thức IF như sau:
=IF(COUNTIF(B5:F5,"<65"),"","✓")
Trong phiên bản của công thức, logic tương tự như công thức gốc ở trên. Tuy nhiên, chúng tôi đã chuyển dấu kiểm sang đối số value_if_false, vì vậy, dấu kiểm sẽ chỉ xuất hiện nếu số đếm từ COUNTIF bằng 0. Nói cách khác, dấu kiểm sẽ chỉ xuất hiện khi không tìm thấy giá trị nào nhỏ hơn 65.
Lưu ý: bạn cũng có thể sử dụng định dạng có điều kiện để đánh dấu đầu vào hợp lệ hoặc không hợp lệ và xác thực dữ liệu để hạn chế đầu vào chỉ cho phép dữ liệu hợp lệ.
