Công thức chung
=IF(criteria,formula(),"")
Tóm lược
Để chạy công thức chỉ khi một hoặc nhiều ô không trống, bạn có thể sử dụng hàm IF với tiêu chí logic thích hợp. Trong ví dụ được hiển thị, công thức trong E5 là:
=IF(COUNT(C5:C7)=3,SUM(C5:C7),"")
Vì C7 không có giá trị trong màn hình trên nên công thức không hiển thị kết quả. Trong màn hình bên dưới, C7 chứa một số và tổng được hiển thị:
Giải trình
Mục tiêu của ví dụ này là xác minh đầu vào trước khi tính toán kết quả. Điểm mấu chốt cần hiểu là bất kỳ công thức hợp lệ nào cũng có thể được thay thế. Hàm SUM chỉ được dùng làm ví dụ. Logic cũng có thể được điều chỉnh theo nhiều cách để phù hợp với tình huống.
Trong ví dụ được hiển thị, chúng tôi đang sử dụng hàm IF cùng với hàm COUNT. Tiêu chí là một biểu thức dựa trên hàm COUNT, hàm này chỉ đếm các giá trị số:
COUNT(C5:C7)=3 // returns TRUE or FALSE
Miễn là phạm vi chứa ba số (tức là cả 3 ô không trống) thì kết quả là TRUE và IF sẽ chạy hàm SUM. Nếu không, kết quả là FALSE và IF trả về một chuỗi trống (""). Vì C7 không có giá trị trong màn hình trên nên công thức không hiển thị kết quả.
Có nhiều cách để kiểm tra các ô trống và một số tùy chọn được giải thích bên dưới.
Với COUNTBLANK
Hàm COUNTBLANK đếm các ô trống trong một phạm vi, vì vậy chúng ta có thể viết một công thức nhỏ gọn hơn một chút như sau:
=IF(COUNTBLANK(C5:C7),"",SUM(C5:C7))
Nếu COUNTBLANK trả về bất kỳ số nào ngoại trừ số 0, hàm IF sẽ đánh giá là TRUE và không trả về (""). Nếu COUNTBLANK trả về 0, IF đánh giá là FALSE và trả về tổng.
Với ISBLANK
Trong ví dụ được hiển thị, tất cả các ô đầu vào đều nằm trong cùng một phạm vi liền kề. Trong trường hợp các ô không cùng nhau, bạn có thể sử dụng công thức như sau:
=IF(OR(ISBLANK(C5),ISBLANK(C6),ISBLANK(C7)),"",SUM(C5:C7))
Ví dụ này có cách tiếp cận theo nghĩa đen với hàm ISBLANK. Bởi vì chúng ta muốn kiểm tra tất cả ba ô cùng một lúc, chúng ta cần sử dụng ISBLANK ba lần bên trong hàm OR. Đây là kiểm tra logic bên trong IF:
OR(ISBLANK(C5),ISBLANK(C6),ISBLANK(C7)
Khi OR trả về TRUE (ít nhất một ô trống), IF trả về một chuỗi trống (""). Khi OR trả về FALSE (không có ô nào trống), IF chạy hàm SUM và trả về kết quả:
SUM(C5:C7)
Với các toán tử logic
Hàm ISBLANK có thể được thay thế bằng các toán tử logic tiêu chuẩn như sau:
=IF(OR(C5="",C6="",C7=""),"",SUM(C5:C7))
Ngoài ra, chúng ta có thể kết hợp toán tử không bằng () với hàm AND như sau:
=IF(AND(C5"",C6"",C7""),SUM(C5:C7),"")
Lưu ý rằng hàm SUM đã được chuyển đến kết quả TRUE. Nó sẽ chỉ chạy nếu C5 và C6 và C5 không trống.
Với COUNTA
Cuối cùng, bạn có thể sử dụng hàm COUNTA để kiểm tra kiểu nhập số hoặc văn bản:
=IF(COUNTA(C5:C7)=3,SUM(C5:C7),"")
Miễn là phạm vi C5: C5 chứa ba giá trị (số hoặc văn bản), kết quả sẽ là TRUE và hàm SUM sẽ chạy. Điều này không thực sự có ý nghĩa đối với ví dụ được hiển thị (yêu cầu nhập số) nhưng nó có thể được sử dụng trong các trường hợp khác.
